docs-v2/content/flux/v0.x/stdlib/universe/display.md

title	description	menu	weight	introduced
display() function	`display()` returns the Flux literal representation of any value as a string.	flux_0_x_ref name parent display universe	102	0.154.0

display() returns the Flux literal representation of any value as a string.

display(v: "example value")

Basic types are converted directly to a string. Bytes types are represented as a string of lowercase hexadecimal characters prefixed with 0x. Composite types (arrays, dictionaries, and records) are represented in a syntax similar to their equivalent Flux literal representation.

Note the following about the resulting string representation:

• It cannot always be parsed back into the original value.
• It may span multiple lines.
• It may change between Flux versions.

{{% note %}} display() differs from string() in that display() recursively converts values inside composite types to strings. string() does not operate on composite types. {{% /note %}}

Parameters

v

Value to convert for display.

Examples

• Display composite values as part of a table
• Display a record
• Display an array
• Display a dictionary
• Display bytes
• Display a composite value

Display composite values as part of a table

Use array.from() and display() to quickly observe any value.

import "array"

array.from(
    rows: [
        {
            dict: display(v: ["a":1, "b": 2]),
            record: display(v:{x: 1, y: 2}),
            array: display(v: [5,6,7])
        }
    ]
)

Output data

dict	record	array
[a: 1, b: 2]	{x: 1, y: 2}	[5, 6, 7]

Display a record

x = {a: 1, b: 2, c: 3}

display(v: x)

// Returns {a: 1, b: 2, c: 3}

Display an array

x = [1, 2, 3]

display(v: x)

// Returns [1, 2, 3]

Display a dictionary

x = ["a": 1, "b": 2, "c": 3]

display(v: x)

// Returns [a: 1, b: 2, c: 3]

Display bytes

x = bytes(v:"abc")

display(v: x)

// Returns 0x616263

Display a composite value

x = {
    bytes: bytes(v: "abc"),
    string: "str",
    array: [1,2,3],
    dict: ["a": 1, "b": 2, "c": 3],
}

display(v: x)

// Returns
// {
//    array: [1, 2, 3],
//    bytes: 0x616263,
//    dict: [a: 1, b: 2, c: 3],
//    string: str
// }